照明论坛-LED论坛-照明家族

标题: 15-LTspice .SUBCKT MOV代码解析 [打印本页]

作者: fdsadfdsid 时间: 2021-7-11 22:28
标题: 15-LTspice .SUBCKT MOV代码解析
.SUBCKT MOV 1 2
* model of Panasonic ERZV05D221 5mm diameter disc, 140 VAC max, 180 VDC max,
* 380 Vmax @ 5A, 9 joules max. in 10 to 1000 us.
*http://www.panasonic.com/industrial/components/pdf/awa0000ce2.pdf
.param a=46671.474 b=256.579 c=102.242 d=9.57176 f=7.9462*10**8 g=0.142
Rmov 1 3 R=a*exp(d*atan((b-ABS(V(1,3)))/c))
Rpar 1 3 {f}
Rser 3 2 {g}
Cpar 1 3 110p
.ENDS

作者: 888888 时间: 2021-7-14 08:42
* Vishay VDR (voltage dependent resistors) included in this file : VDRS/VDRH/VDRUS
* DESCRIPTION: through hole VDR (Varistors)
* For electrical limitations, see
* VDRS : http://www.vishay.com/docs/29081/vdrs.pdf
* VDRH : http://www.vishay.com/varistors/list/product-29082
* VDRUS :http://www.vishay.com/varistors/list/product-29185
* or use the search engine of Vishay for visualizing particular data sheet at http://www.vishay.com/

.SUBCKT VDR_BASE_MODEL 1 2  PARAMs:  B1=1 B2=1 B3=1 B4=1  L=1h C=1pf  T=1
C_C1       2 4  {C}  TC=0,0
V_V1       4 5 0Vdc
E_E1       5 2 VALUE { T*(
+ PWR(10,
+  B1+B2*(LOG10(LIMIT(V(6),1m,100G))-4)+B3*EXP(-LOG10(LIMIT(V(6),1m,100G))+4)+B4*EXP(LOG10(LIMIT(V(6),1m,100G))-4)
+ )
+ -PWR(10,
+  B1+B2*(LOG10(-LIMIT(V(6),-100G,-1m))-4)+B3*EXP(-LOG10(-LIMIT(V(6),-100G,-1m))+4)+B4*EXP(LOG10(-LIMIT(V(6),-100G,-1m))-4)
+ )
+ +LIMIT((V(6)*1K*V(7)),-V(7),V(7))
+ ) }
E_E2       6 0 VALUE { +(I(V_V1))*10K }
R_R1       3 1  100u TC=0,0
L_L1       4 3  {L}
R_R3       0 6  1T TC=0,0
R_R4       0 7  1T TC=0,0
E_E3       7 0 VALUE { PWR(10,(B1+B2*(-7)+B3*EXP(+7)+B4*EXP(-7))) }
.ENDS
*$
*
.SUBCKT VDRH05B011 1  2 PARAMS: TOL=0
X1  1 2 VDR_BASE_MODEL  PARAMS: T = {1+TOL/100}  C= 1600pF  L=8nH  B1= 1.48784225352783
+  B2=0.0723488092666941  B3=-0.000219701399205325  B4=0.0249934940562207
.ENDS

欢迎光临照明论坛-LED论坛-照明家族 (http://lightingfamily.net/)